Tiempo sidéreo

El TIEMPO SIDÉREO DE GREENWICH A 0 H. DE TU es el ángulo horario que forma el meridiano Greenwhich con el punto Aries a 0 horas de T.U.
Viene dado por la expresión de Newcomb:
TS(0h, GR)=6h 38m 45,836s +8640184,542s . T+0,0929s . T²
siendo T el número de siglos julianos de 36525 días transcurridos, hasta la medianoche de Greenwich, desde el mediodía de Greenwich del 0 de Enero de 1900 es decir desde el 31 de Diciembre de 1899 a las 12 h de TU.
Como la fecha juliana de este instante DJ(t0)=2415020 resulta T=(JD-2415020)/36525 siendo JD la fecha juliana del instante a 0h en que queremos calcular el tiempo sidéreo.

Un programa Basic nos ayuda:

160 CLS:PRINT "TIEMPO SIDÉREO DE GREENWHICH A 0 H. DE T.U."
165 INPUT "ENTRE DIA,MES,AÑO ";DY,MN,YR
168 HR=0:MI=0:SG=0
170 GOSUB 1610
180 END
1610 REM SUBPRG. CONVERSION  TU A T. SIDÉREO
1640 DD=DY+HR/24+MI/1440+SG/86400!
1670 DY=INT(DD)
1680 REM CONVERSION A FECHA JULIANA
1690 IF MN=1 OR MN=2 THEN YR=YR-1:MN=MN+12
1700 IF YR+MN/100+DY/10000=>1582.1015# THEN
           GR=2-INT(YR/100)+INT(INT(YR/100)/4) ELSE GR=0
1710 JD#=INT(365.25*YR)+INT(30.6001*(MN+1))+DY+1720994.5# +GR
1720 T#=(JD#-2415020#)/36525!
1730 SS#=6.6460656#+2400.051*T#+.00002581#*T#*T#
1740 ST#=(SS#/24-INT(SS#/24))*24
1745 HR#=INT(ST#):MI#=(ST#-HR#)*60:SG=(MI#-INT(MI#))*60
1750 PRINT "TIEMPO SIDÉREO A 0 HR DE TU EN GREENWHICH=";
INT (ST#);" H";INT(MI#);"MIN";SG;"SG"
1755 RETURN

Ejemplo: Cálculo del Tiempo sidéreo Greenwich a 0 horas de TU del 13 Noviembre de 1978. Calcula previamente la fecha juliana para hacerlo manualmente.
sol bibliografía: Hora sidérea de Greenwich a 0 TU=3 h 27 m 1.33s
sol programa:=3 h 27 m 0.66 s
Ejemplo: Calcular el tiempo sidéreo de Greenwich a 0h TU del 31 julio de 1981. Calcula previamente la fecha juliana para hacerlo manualmente.
Sol: TS(0h,GR)=20h 30m 7,697s

Cálculo del tiempos sidéreo local a un TU dado

La relación entre los intervalos de tiempo sidéreo y solar o medio es:

S=M+0,00273784 M
M=S-0,00273032 S

así que para calcular el tiempo sidéreo en Greenwich a un tiempo t (TU), basta con transformar este intervalo en sidéreo:
TS(t (TU), GR)=TS(0h, GR)+ 1,002737847 t (TU)

Ejemplo: Calcular el tiempo sidéreo a las 2h 18m TU de Grenwich del 31 de julio de 1981.

En el caso que nos ocupa: TS (t,GR)=20h 30m 7,697s+1,002737847. 2,3= 22,87510 h=22h 52m 30,36s

Ejemplo:Calcular en La Coruña con longitud 33 m 33.9 s W el Tiempo Sidéreo local el día 13-7-1976 a las 3 h 17 m 28 s de TU:

Solución bibliografía: es 22 h 8 m 26.8 s
Solución del programa 22 h 8 m 25.50 s

El programa Basic que nos facilita el cálculo:
(el subprograma en 1610, es el ya citado)

250 CLS: PRINT "CALCULO DEL T. SIDÉREO LOCAL A UN T.U. DADO"
260 INPUT "ENTRE DIA,MES,AÑO ";DY,MN,YR
270 INPUT "ENTRE HORAS,MIN SEG (TU) ";HR,MI,SG
280 PRINT "ENTRE SU LONGITUD GEOGRAF. EN GRD DECIMALES :"
290 INPUT "Long (- al w) (+ al E) de GREENWICH ";LG
300 GOSUB 1610
310 SA#=ST#+(DD-INT(DD))*24*1.002737908#
320 SA#=SA#+LG/15
330 IF SA#<0 THEN SA#=SA#+24
340 IF SA#>24 THEN SA#=SA#-24
350 HR#=INT(SA#):MI#=(SA#-HR#)*60:SG=(MI#-INT(MI#))*60
360 PRINT "TIEMPO SIDEREO LOCAL=";INT (SA#);" H";INT(MI#);"MIN";SG;"SG"
370 END

DEFINICIÓN DE LOS DISTINTOS TIPOS DE TIEMPOS

Se llama TIEMPO SOLAR MEDIO en un lugar al ángulo horario que forma el Sol con el meridiano del lugar.
El TIEMPO CIVIL LOCAL (TCL) es el tiempo solar medio aumentado en 12 horas.
Se llama TIEMPO UNIVERSAL (TU) al TCL de GREENWICH
El TIEMPO SIDÉREO DE GREENWICH A 0 H. DE TU es el ángulo horario que forma el meridiano Greenwhich con el punto ARIES a 0 horas de T.U.
El TIEMPO SIDÉREO LOCAL es el ángulo que forma el meridiano del lugar con el punto ARIES en un instante dado.
Entre el TCL y el TU al igual que entre el TIEMPO SIDÉREO LOCAL y el TIEMPO SIDÉREO DE GREENWHICH existe una relación dada por la diferencia de longitudes entre el lugar y Greenwhich.

This HTML document was created by GT_HTML 6.0 26/1/98 13:43.