Listado del programa

1 REM CALCULO CURVAS DE IGUAL MAGNITUD ECIPSE SOLAR (MEEUS) #22   SAVE...ESM22
2 PI=3.14159265#:SCREEN 0:WIDTH 80
3 DEF FN AS(X)=ATN(X/SQR(1-X*X))
4 DEF FN AC(X)=-ATN(X/SQR(1-X*X))+PI/2
10 REM LEER FICHERO ECLIPSE.BIN      SAVE...MEEUS6
20 DEFDBL J,M
30 OPEN "R",#1, "ECLIPSE.BIN",117
40 FIELD #1, 2 AS A$,1 AS M$,1 AS D$,1 AS T$,4 AS F$,4 AS G$,8 AS J$,2 AS K$,1 AS S$,1 AS T0$,4 AS X0$,4 AS X1$,4 AS X2$,4 AS X3$,76 AS Z1$
50 FIELD #1, 41 AS Z2$,4 AS Y0$,4 AS Y1$,4 AS Y2$, 4 AS Y3$,4 AS D0$, 4 AS D1$,4 AS D2$,8 AS M0$,8 AS M1$,32 AS Z3$
60 FIELD #1, 85 AS Z4$,4 AS L10$, 4 AS L11$,4 AS L12$,4 AS L20$,4 AS L21$,4 AS L22$,4 AS F1$, 4 AS F2$
70 FOR S=1 TO 6
80 READ TIPO$
90 TP$(S)=TIPO$
100 NEXT S
110 DATA ECLIPSE PARCIAL,ECLIPSE CENTRAL TOTAL,ECLIPSE CENTRAL ANULAR,ECLIPSE ANULAR NO CENTRAL,ECLIPSE TOTAL NO CENTRAL,ECLIPSE ANULAR-TOTAL
120 CLS:PRINT "ELEMENTOS BESSELIANOS DE UN ECLIPSE SOLAR (PERIODO 1951-2200)"
130 PRINT "============================================================="
140 INPUT "NUMERO DEL ECLIPSE EN EL PERIODO (menor que 571)=";NUM
150 IF NUM>570 THEN 120
160 GET #1,NUM
170 PRINT "A¥O=";CVI(A$);"  MES=";ASC(M$)-64;"   DIA=";ASC(D$)-64
180 DT=29.1+.7026*(CVI(A$)-1950)
190 FE$=STR$(ASC(D$)-64)+"-"+STR$(ASC(M$)-64)+"-"+STR$(CVI(A$))
200 FM=CVS(F$):TIPO=ASC(T$)-64
210 PRINT "TIPO=";TP$(TIPO);
220 IF ASC(T$)=65 THEN PRINT "  FASE MAX.=";CVS(F$) ELSE PRINT "  "
230 PRINT "GAMMA=";CVS(G$)
240 PRINT
250 PRINT "JDE=";CVD(J$);"   K=";CVI(K$);"   SAROS=";ASC(S$)
260 PRINT "T0=";ASC(T0$)-64
270 T0=ASC(T0$)-64
280 PRINT
290 PRINT "X0=";CVS(X0$);"   X1=";CVS(X1$);"   X2=";CVS(X2$);"   X3=";CVS(X3$)
300 X0=CVS(X0$):X1=CVS(X1$):X2=CVS(X2$):X3=CVS(X3$)
310 PRINT "Y0=";CVS(Y0$);"   Y1=";CVS(Y1$);"   Y2=";CVS(Y2$);"   Y3=";CVS(Y3$)
320 Y0=CVS(Y0$):Y1=CVS(Y1$):Y2=CVS(Y2$):Y3=CVS(Y3$)
330 PRINT
340 PRINT "d0=";CVS(D0$);"    d1=";CVS(D1$);"    d2=";CVS(D2$)
350 D0=CVS(D0$):D1=CVS(D1$):D2=CVS(D2$)
360 PRINT "M0=";CVD(M0$);"    M1=";CVD(M1$)
370 M0=CVD(M0$):M1=CVD(M1$)
380 PRINT
390 PRINT "L10=";CVS(L10$);"   L11=";CVS(L11$);"   L12=";CVS(L12$)
400 L10=CVS(L10$):L11=CVS(L11$):L12=CVS(L12$)
410 PRINT "L20=";CVS(L20$);"   L21=";CVS(L21$);"   L22=";CVS(L22$)
420 L20=CVS(L20$):L21=CVS(L21$):L22=CVS(L22$)
430 PRINT "TAN f1=";CVS(F1$);"   TAN f2=";CVS(F2$)
440 F1=CVS(F1$):F2=CVS(F2$)
442 LOCATE 4,35:PRINT "DIFERENCIA TD Y TU (SEG) =";:PRINT USING "####.##";DT
444 LOCATE 4,35:INPUT "DIFERENCIA TD Y TU (SEG) =";DT
450 LOCATE 21,5:PRINT "Pulse O para otro eclipse"
460 LOCATE 22,5:PRINT "Pulse C para calcular el eclipse"
470 Z$=INKEY$ :IF Z$="" THEN 470
480 IF Z$="c" OR Z$="C" THEN 500 ELSE 120
490 REM CALCULO DEL ECLIPSE SOLAR (2ø metodo para longitudes dadas)
500 CLS:PRINT "ECLIPSE SOLAR DEL  ";FE$;"    ";TP$(TIPO);" ";
510 IF TIPO=1 THEN PRINT "FASE MAXIMA=";FM ELSE PRINT
520 PRINT "==================================================================="
530 PRINT "CURVAS DE IGUAL MAGNITUD "
540 PRINT "INGRESAR LA LONGITUD GEOGRAFICA "
550 INPUT "LONGITUD (+W en grados) =";LG
570 INPUT "MAGNITUD=";G
580 IF TIPO=1 AND G>FM THEN PRINT "INGRESE VALOR MENOR QUE LA FASE MAXIMA ";FM:GOTO 570
590 I=1:LIM$="NORTE":J=0:REM INICIACION ITERACION LIMITE NORTE
600 T=0:FI=0: REM VALORES INICIALES
610 J=J+1:T2=T*T:T3=T2*T:REM COMIENZO ITERACION
620 X=X0+X1*T+X2*T2+X3*T3
630 Y=Y0+Y1*T+Y2*T2+Y3*T3
640 D=D0+D1*T+D2*T2
650 M=M0+M1*T
660 REM VARIACIONES DIARIAS
670 VX=X1+2*X2*T+3*X3*T2
680 VY=Y1+2*Y2*T+3*Y3*T2
690 H=M-LG-4.17807E-03*DT
700 REM COORDENADAS GEOCENTRICAS
710 FU=ATN(.99664719#*TAN(FI*PI/180))
720 RSIN=.99664719#*SIN(FU)
730 RCOS=COS(FU)
740 REM CALCULOS DE P,Q,R
750 D=D*PI/180:H=H*PI/180
760 P=RCOS*SIN(H)
770 Q=RSIN*COS(D)-RCOS*COS(H)*SIN(D)
780 R=RSIN*SIN(D)+RCOS*COS(H)*COS(D)
790 VP=1.745329E-02*M1*RCOS*COS(H)
800 VQ=1.745329E-02*(M1*P*SIN(D)-R*D1)
810 U=X-P:V=Y-Q
820 A=VX-VP:B=VY-VQ
830 N=SQR(A*A+B*B)
840 TAU=-(U*A+V*B)/(N*N)
850 T=T+TAU
860 L1=L10+L11*T+L12*T2
870 L2=L20+L21*T+L22*T2
880 L1P=L1-R*F1
890 L2P=L2-R*F2
900 REM CORRECCION PARA LA LATITUD
910 E=L1P-G*(L1P+L2P)
920 CW=(V*A-U*B)/N
930 CQ=(B*SIN(H)*RSIN+A*(COS(H)*SIN(D)*RSIN+COS(D)*RCOS))/(57.29578*N)
940 CFI=(CW+I*ABS(E))/CQ
950 FI=FI+CFI
960 IF J>20 THEN 1060
970 IF ABS(TAU)>.000001 THEN 610
980 IF ABS(CFI)<.00001 THEN 990 ELSE 610
990 PRINT :PRINT "VALORES DE LATITUD Y TIEMPO PARA EL LIMITE ";LIM$
995 AN=FI:GOSUB 3450
1000 PRINT "LATITUD GEOGRAFICA=";FI;"=";GR;" ø";MI;" '";INT(SG);" ''"
1010 TD=T0+T:TU=TD-DT/3600
1015 AN=TD:GOSUB 3450
1020 PRINT "INSTANTE (TD)=";TD;"=";GR;" h";MI;" m";INT(SG);" s"
1025 AN=TU:GOSUB 3450
1030 PRINT "INSTANTE (TU)=";TU;"=";GR;" h";MI;" m";INT(SG);" s"
1040 IF I=1 THEN 1050 ELSE 1080
1050 J=0:I=-1:LIM$="SUR":GOTO 600
1060 PRINT :PRINT "NO EXISTE EL LIMITE ";LIM$
1070 IF I=1 THEN 1050
1080 END
3450 REM conversion a sistema sexagesimal
3460 A1=ABS(AN)
3470 GR=SGN(AN)*INT (A1)
3480 MI=INT((A1-INT(A1))*60)
3490 SG=((A1-INT(A1))*60-MI)*60
3500 RETURN